This article explains How to display Wi-Fi Password on Desktop.
Wi-Fi Passwords List
First you need to get a list of Wi-Fi passwords that you have ever connected. In this article, I will use a vbscript file to get a list of Wi-Fi passwords. You copy the following command and save the file with the extension "VBS".
Option Explicit
Dim Ws,AppData,Wifi_Folder,fso,f,Data
Dim SSID,KeyPassword,ExportCmd,oFolder,File,Info,LogFile
LogFile = Left(Wscript.ScriptFullName,InstrRev(Wscript.ScriptFullName, ".")) & "txt"
Set Ws = CreateObject("Wscript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")
AppData = ws.ExpandEnvironmentStrings("%AppData%")
Wifi_Folder = AppData & "\Wifi"
If Not fso.FolderExists(Wifi_Folder) Then fso.CreateFolder(Wifi_Folder)
ExportCmd = "Cmd /C netsh wlan export profile key=clear folder="& Wifi_Folder &""
ws.run ExportCmd,0,True
Set oFolder = fso.GetFolder(Wifi_Folder)
Info = String(40,"-") & vbCrlf & Space(4) &_
"SSID" & Space(3) &":"& Space(3) & "Password" & vbCrlf &_
String(40,"-") & vbCrlf
For Each File in oFolder.Files
If UCase(fso.GetExtensionName(File.Name)) = "XML" Then
Set f=fso.opentextfile(File,1)
Data = f.ReadAll
SSID = Extract(Data,"(?:<name>)(.*)(?:<\/name>)")
KeyPassword = Extract(Data,"(?:<keyMaterial>)(.*)(?:<\/keyMaterial>)")
Info = Info & qq(SSID) & ":" & qq(KeyPassword) & vbCrlf
End If
Next
MsgBox Info,vbInformation
Call WriteLog(Info,LogFile)
If fso.FileExists(LogFile) Then ws.run qq(LogFile)
'---------------------------------------------------------------------------------------------
Function Extract(Data,Pattern)
Dim oRE,colMatches,Match,numMatches,myMatch
Dim numSubMatches,subMatchesString,i,j
set oRE = New RegExp
oRE.IgnoreCase = True
oRE.Global = False
oRE.MultiLine = True
oRE.Pattern = Pattern
set colMatches = oRE.Execute(Data)
numMatches = colMatches.count
For i=0 to numMatches-1
'Loop through each match
Set myMatch = colMatches(i)
numSubMatches = myMatch.submatches.count
'Loop through each submatch in current match
If numSubMatches > 0 Then
For j=0 to numSubMatches-1
subMatchesString = subMatchesString & myMatch.SubMatches(0)
Next
End If
Next
Extract = subMatchesString
End Function
'---------------------------------------------------------------------------------------------
Function qq(str)
qq = Chr(34) & str & Chr(34)
End Function
'---------------------------------------------------------------------------------------------
Sub WriteLog(strText,LogFile)
Dim fs,ts
Const ForWriting = 2
Set fs = CreateObject("Scripting.FileSystemObject")
Set ts = fs.OpenTextFile(LogFile,ForWriting,True)
ts.WriteLine strText
ts.Close
End Sub
'---------------------------------------------------------------------------------------------When you run the vbscript file you will get a file containing a list of wireless networks and the corresponding wifi password.
Bginfo
To display this list on your desktop I use bginfo. Download Url: https://docs.microsoft.com/en-us/sysinternals/downloads/bginfo
Next you configure to display the list of wifi passwords from the file obtained from the previous step. With bginfo you can display a lot of information about your computer. What information are you showing on your desktop leave a comment. You name it as you like.
Next you choose your own profile to display your Wi-Fi password list. If you remove the title the display will be better.
That way you see a list of wireless networks in the corresponding password displayed on your desktop.
Facebook: https://www.facebook.com/routerbest
Twitter: https://twitter.com/routerbestcom
